본문 바로가기
Embedded/Arduino

arduino_v220427

Aryazoa 2022. 4. 27. 10:11

온습도 센서 사용

#include "DHT.h" // DHT 라이브러리 호출
 
#define DHTPIN A0     // 온습도 센서가 A0번에 연결
#define DHTTYPE DHT11   // DHT11 온습도 센서 사용

 
DHT dht(DHTPIN, DHTTYPE); // DHT 설정 (4,DHT11) 
 
void setup() {
  Serial.begin(9600); // 통신속도 9600으로 통신 시작
}
 
void loop() {
  int h = dht.readHumidity(); // 습도값을 h에 저장
  int t = dht.readTemperature(); // 온도값을 t에 저장
 
  Serial.print("습도: "); 
  Serial.print(h); // 습도값 출력
  Serial.print("% ");
  Serial.print("온도: ");
  Serial.print(t); // 온도값 출력
  Serial.println("C");
 
  delay(1000);
}

DHT11.zip
0.00MB

센서가 어두워지면 LED 켜짐 방식 변경

#define THR 350
 
int ledArr[] = {11,10,9,6,5,3}; // 사용하는 LED번호
int ledSize = sizeof(ledArr)/ sizeof(ledArr[0]);
int ledCount = 0;
int flag = 0;
 
int modeCount = 0;
 
unsigned long fade_previousMillis = 0;
unsigned long previousMillis = 0;
      
const long interval = 150;
 
void setup()
{
  for(int i=0; i<ledSize; i++)
  	pinMode(ledArr[i], OUTPUT);
 
  pinMode(A0,INPUT);
  
  Serial.begin(9600);
}
 
void led_off()
{
  for(int i=0; i<ledSize; i++)
      digitalWrite(ledArr[i], LOW);
}
 
void led_blink(int count)
{
  if(count%2 == 0){ 
    for(int i=0; i<ledSize; i++){
      digitalWrite(ledArr[i], HIGH);
    }
  }
  else{
    for(int i=0; i<ledSize; i++){
      digitalWrite(ledArr[i], LOW);
    }
  }
}
 
void led_up2dn(int count)
{
  int n = count % (ledSize+1);
  for(int i =0; i<ledSize; i++){
    if (i == n)
      digitalWrite(ledArr[i], HIGH);
    else
      digitalWrite(ledArr[i], LOW);
  }
}
 
void led_dn2up(int count)
{
  int n = count % (ledSize+1);
  for(int i=ledSize-1; i>=0; i--){
    if (i == (ledSize-1-n))
      digitalWrite(ledArr[i], HIGH);  
    else
      digitalWrite(ledArr[i], LOW);  
  }
}
 
void led_weighted_up2dn(int count)
{
  int n = count % (ledSize+1);
  if (n == ledSize)
    led_off();
  else
  	digitalWrite(ledArr[n], HIGH);
}
 
void led_weighted_dn2up(int count)
{
  int n = count % (ledSize+1);
  if (n == ledSize)
    led_off();
  else
  	digitalWrite(ledArr[ledSize-1-n], HIGH); 
}
 
 
void mode_selection(int mode)
{
  switch(mode%6){
    case 0:
    	led_blink(ledCount);
    	ledCount++;
    	break;
    case 1:
    	led_up2dn(ledCount);
    	ledCount++;
    	break;
    case 2:
    	led_dn2up(ledCount);
    	ledCount++;
    	break;
    case 3:
    	led_weighted_up2dn(ledCount);
    	ledCount++;
    	break;
    case 4:
    	led_weighted_dn2up(ledCount);
    	ledCount++;
    	break;
    default:
    	led_off();
    	break;
  }
}
 
void loop() {
  int inputValue = analogRead(A0);
  Serial.print("Sensor : ");
  Serial.print(inputValue);
  Serial.print(" Mode : ");
  Serial.println(modeCount);
  if (inputValue < THR){
    if(flag == 0){
      flag = 1;
      modeCount++;
      ledCount = 0;
      led_off();
      delay(150);
    }
  }
  else if(inputValue > (THR+150)){
    if(flag == 1){
      flag = 0;
    }
  }
  
  unsigned long currentMillis = millis();
  if (currentMillis - previousMillis >= interval) {
    previousMillis = currentMillis;
    mode_selection(modeCount);
  }
}

명령어에 따라 LED제어(시리얼 통신)

int ledArr[] = {11,10,9,6,5,3};
const long interval = 100;
 
String str;
int ledSize = sizeof(ledArr) / sizeof(ledArr[0]);
 
unsigned long previousMillis = 0;
int modeSelect = 0;
int ledCount = 0;
 
#define LED_OFF 0
#define LED_ON 1
#define LED_UP 2
#define LED_DOWN 3
 
 
void setup()
{
  for(int i=0; i<ledSize; i++)
  	pinMode(ledArr[i], OUTPUT);
  Serial.begin(9600); // 시리얼 통신 시작
}
 
void led_on()
{
  for(int i=0; i<ledSize; i++){
    digitalWrite(ledArr[i],HIGH);
  }
}
 
void led_off()
{
  for(int i=0; i<ledSize; i++){
    digitalWrite(ledArr[i],LOW);
  }
}
 
void led_up(int count)
{
  
  int i = ledSize - 1 - (count % ledSize);
  for(int n=0; n<ledSize; n++){
    if(n==i)
      digitalWrite(ledArr[n], HIGH);
    else
      digitalWrite(ledArr[n], LOW);
  }
}
void led_dn(int count)
{
  int i = count % ledSize;
  for(int n=ledSize-1; n>=0; n--){
    if(n==i)
      digitalWrite(ledArr[n], HIGH);
    else
      digitalWrite(ledArr[n], LOW);
  }
}
 
void mode_selector(int mode)
{
  switch(mode){
    case LED_ON:
      led_on();
      break;
    case LED_OFF:
      led_off();
      break;
    case LED_UP:
      led_up(ledCount);
      break;
    case LED_DOWN:
      led_dn(ledCount);
      break;
  }
}
 
 
void loop()
{
  if(Serial.available() > 0){
    str = Serial.readStringUntil('\n');
    Serial.print(str);
    if(str == "on" || str == "ON"){
      modeSelect = LED_ON;
      Serial.println(" : LED 켜짐");
    }
    else if(str == "off" || str == "OFF"){
      modeSelect = LED_OFF;
      Serial.println(" : LED 꺼짐");
    }
    else if(str == "up" || str == "UP"){
      modeSelect = LED_UP;
      mode_selector(LED_OFF);
      ledCount = 0;
      Serial.println(" : LED 위에서 아래로");
    }
    else if(str == "dn" || str == "DN" || 
            str == "down" || str == "DOWN"){
      modeSelect = LED_DOWN;
      mode_selector(LED_OFF);
      ledCount = 0;
      Serial.println(" : LED 아래에서 위로");
    }            
    else{
      Serial.println(" : 입력한 명령어가 없습니다.");
    }
  }
  
  unsigned long currentMillis = millis();
  if (currentMillis - previousMillis >= interval){
    previousMillis = currentMillis;
    mode_selector(modeSelect);
    ledCount++;
  }
}

 

밝기값에 따라 0~6개 LED켜짐

int ledArr[] = {11,10,9,6,5,3};
int ledSize = sizeof(ledArr) / sizeof(ledArr[0]);
 
void setup()
{
  for(int i=0; i<ledSize; i++)
  	pinMode(ledArr[i], OUTPUT);
  
  pinMode(A0, INPUT);
  Serial.begin(9600); // 시리얼 통신 시작
}
 
void led_add_on(int level)
{
  for(int i=0; i<ledSize; i++){
    digitalWrite(ledArr[i],LOW);
  }
  
  for(int i=0; i<level; i++){
    digitalWrite(ledArr[i],HIGH);
  }
}
 
void loop()
{
  int sensorValue = analogRead(A0);
  int ledLevel = map(sensorValue, 0,1023, 0,ledSize+1);
  Serial.print("Sensor value : ");
  Serial.print(sensorValue);
  Serial.print(" map : ");
  Serial.println(ledLevel);
  
  led_add_on(ledLevel);
}

포토레지스터 + LED 추가

int thr = 350;

void setup()
{
	Serial.begin(9600);
	pinMode(A0, INPUT);
	pinMode(9,OUTPUT);
	pinMode(10,OUTPUT);
	pinMode(11,OUTPUT);
}

void loop()
{
	int sensorValue = analogRead(A0);
	Serial.print("Sensor : ");
	Serial.println(sensorValue);
	
	if(sensorValue < thr){
		digitalWrite(9,HIGH);
		digitalWrite(10,HIGH);
		digitalWrite(11,HIGH);
	}else{
		digitalWrite(9,LOW);
		digitalWrite(10,LOW);
		digitalWrite(11,LOW);
	}
}

 

포토레지스터

void setup()
{
	Serial.begin(9600);
	pinMode(A0, INPUT);
}

void loop()
{
	int sensorValue = analogRead(A0);
	Serial.print("Sensor : ");
	Serial.println(sensorValue);
	delay(500);
}

 

핑크

// Pink R:255 G:192 B:203
void setup()
{
  pinMode(11, OUTPUT);
  pinMode(10, OUTPUT);
  pinMode(9, OUTPUT);
}

void loop()
{
  analogWrite(11, 255);
  analogWrite(10, 192);
  analogWrite(9, 203);
  delay(1000);
  analogWrite(11, 0);
  analogWrite(10, 0);
  analogWrite(9, 0);
  delay(1000);
}

// C++ code
//

# define RED 11
# define GREEN 10
# define BLUE 9

void setup()
{
  pinMode(BLUE, OUTPUT);
  pinMode(GREEN, OUTPUT);
  pinMode(RED, OUTPUT);
}

void loop()
{
  //White
  digitalWrite(BLUE, HIGH);
  digitalWrite(GREEN, HIGH);
  digitalWrite(RED, HIGH);
  delay(500); 
  digitalWrite(BLUE, LOW);
  digitalWrite(GREEN, LOW);
  digitalWrite(RED, LOW);
  delay(500);
  //Yellow 
  digitalWrite(RED, HIGH);
  digitalWrite(GREEN, HIGH);
  delay(500); 
  digitalWrite(RED, LOW);
  digitalWrite(GREEN, LOW);
  delay(500); 
  //Cyan(청록)
  digitalWrite(BLUE, HIGH);
  digitalWrite(GREEN, HIGH);
  delay(500); 
  digitalWrite(BLUE, LOW);
  digitalWrite(GREEN, LOW);
  //Magenta(자주)
  digitalWrite(BLUE, HIGH);
  digitalWrite(RED, HIGH);
  delay(500); 
  digitalWrite(BLUE, LOW);
  digitalWrite(RED, LOW);
  delay(500);
  //ORANGE
  analogWrite(GREEN, 127);
  analogWrite(RED, 255);
  delay(500); 
  analogWrite(GREEN, 0);
  analogWrite(RED, 0);
  delay(500);
  
  digitalWrite(BLUE, HIGH);
  delay(500); 
  digitalWrite(BLUE, LOW);
  delay(500); 
  digitalWrite(GREEN, HIGH);
  delay(500); 
  digitalWrite(GREEN, LOW);
  delay(500); 
  digitalWrite(RED, HIGH);
  delay(500); 
  digitalWrite(RED, LOW);
  delay(500); 
}

'Embedded > Arduino' 카테고리의 다른 글

lilyPad_v220428  (0) 2022.04.28
Arduino_v220428 - piezo only  (0) 2022.04.28
arduino_v220425  (0) 2022.04.25
아두이노+RC카+적외선센서 제어  (0) 2021.12.30
CAN Example #3  (0) 2021.11.29

'Embedded/Arduino' Related Articles

티스토리툴바